★ 用 Blynk 同時控制多個設備

昨天有網友問我是否可以用 App Inventor 2 設計一個 App 來同時控制多個設備, 以我的菜園灑水控制器來說, 若菜園有多處裝有 Arduino 灑水控制器, 希望在 App 上按一個按鈕就可以控制它們同時灑水或停止. 這讓我馬上想到 Blynk 應該可以輕易完成這個任務, 不需要花時間自行設計一個 App 才對.

以下使用我自行焊接的兩個 Arduino+ESP8266 物聯網模組來測試 Blynk 群控的功能, 利用 App 上的一個 Slider 滑桿元件同時控制 Arduino NANO 板上的 D13 LED 閃爍速度. 此 IOT 模組的製作方式參考 :

# 製作 Arduino Nano + ESP8266 物聯網模組 (四) : 完結篇

也可以根據下列電路圖用洞洞板連線 (AMS1117 可用 3.3V 穩壓模組取代) :

關於 Blynk 的用法, 參考之前的一系列實驗記錄 :

# Blynk 應用 (一) : 用手機控制 Arduino
# Blynk 應用 (二) : 在手機顯示即時溫溼度與光度
# Blynk 的控制元件 (Controllers)
# Blynk 的顯示元件 (Displays)
# Blynk 的通知元件 (Notifications)
# Blynk 的其他元件 (Others)
# Blynk 的虛擬腳位用法整理

在 Blynk App 上則是先新增一個專案, 在此專案中新增一個 Slider M 元件, 然後綁定一個虛擬腳位 V0, 修改值域為 100 ~ 1000, 代表 LED 閃爍的頻率 (其實是延遲時間), 100 表示快閃, 1000 表示慢閃.

此專案分享如下 :

測試程式如下 :

測試 1 :

#define BLYNK_PRINT Serial  //Comment this out to disable prints and save space
#include <SoftwareSerial.h>
#include <ESP8266_Lib.h>
#include <BlynkSimpleShieldEsp8266.h>

SoftwareSerial esp8266(7, 8); //(RX, TX)
ESP8266 wifi(&esp8266); //create wifi object

char ssid[]="H30-L02-webbot";
char pass[]="1234567890";
char auth[]="f4d4aa2dc86849adb0971d0xxxxxx371";
volatile int blinkRate=100;  //default blink rate

void setup() {
  Serial.begin(9600); //Set console baud rate
  esp8266.begin(9600); //Set ESP8266 baud rate
  Blynk.begin(auth, wifi, ssid, pass);
  }

void loop() {
  Blynk.run();
  blinkD13Led(blinkRate);
  }

BLYNK_WRITE(V0) { //called when V0 updated by App slider
  blinkRate=param.asInt(); //store value from App slider
  Serial.println(blinkRate);  //show current blink rate
  }

void blinkD13Led(int t) {
  digitalWrite(13, HIGH);
  delay(t);          
  digitalWrite(13, LOW);
  delay(t);          
  }

此處我們須準備一個特定的寫入事件處理函數 BLYNK_WRITE(V0) 讓 V0 腳位值更新時被呼叫, 因為手機 App 的 Slider 是一個控制元件, 當滑動滑桿時會將滑桿的值寫入伺服器中此專案之虛擬腳位 V0, 產生一個寫入事件, 會觸發設備中的寫入事件處理函數被呼叫一次. 在此函數中, 我們用特定的變數 param 取得最新的 V0 腳位之值, 用來更新全域變數 blinkRate, 此變數會被 blinkD13LED() 用來更改 LED 的閃爍頻率. 跟中斷事件類似, 由於 blinkRate 隨時會被更新, 因此要宣告為 volatile 以避免被編譯器優化.

這兩塊 IOT 模組都上傳相同的程式, 上電後, 由於 blinkRate 初始值設為 100, 因此會先快閃, 等我們滑動滑桿之後就會改變閃爍頻率 :

從上面影片可知, 滑動滑桿時, 兩個 NANO 板上的 D13 LED 都同時改變其閃爍頻率, 可見用 Blynk 可輕易達成群控之目的.

但上面測試 1 有個問題, 即每次重開機預設都是快閃 (blinkRate 預設 100), 必須在 App 上操作滑桿才會變更頻率. 要如何讓設備一開機或重新連線時能以最後一次滑桿之值閃爍呢? 這可以用特定之 BLYNK_CONNECTED() 函數來實現, 此函數會在設備重新與 Blynk Cloud 伺服器連線成功時被呼叫, 我們只要在此事件處理程序中呼叫 Blynk.syncVirtual(vPin) 即可取得伺服器上該虛擬腳位之值, 從而觸發虛擬腳位之寫入動作, 使 BLYNK_WRITE() 函數被呼叫, 這樣就會以上次的設定值閃爍了.

測試 2 :

#define BLYNK_PRINT Serial  //Comment this out to disable prints and save space
#include <SoftwareSerial.h>
#include <ESP8266_Lib.h>
#include <BlynkSimpleShieldEsp8266.h>

SoftwareSerial esp8266(7, 8); //(RX, TX)
ESP8266 wifi(&esp8266); //create wifi object
int blinkRate;

char ssid[]="H30-L02-webbot";
char pass[]="1234567890";
char auth[]="f4d4aa2dc86849adb0971d0xxxxxx371";

void setup() {
  Serial.begin(9600); //Set console baud rate
  esp8266.begin(9600); //Set ESP8266 baud rate
  Blynk.begin(auth, wifi, ssid, pass);
  }

void loop() {
  Blynk.run();
  blinkD13Led(blinkRate);
  }

BLYNK_WRITE(V0) { //called when V0 updated by App slider
  blinkRate=param.asInt(); //store value from App slider
  Serial.println(blinkRate);
  }

BLYNK_CONNECTED() { //get data stored in virtual pin V0 from server
  Blynk.syncVirtual(V0);
  }

void blinkD13Led(int t) {
  digitalWrite(13, HIGH);
  delay(t);        
  digitalWrite(13, LOW);
  delay(t);        
  }

此程式中的 BLYNK_CONNECTED() 會在設備連上 Blynk 伺服器時被呼叫 (全部大寫的函數都是事件處理函數), 在裡面我們呼叫了指定虛擬腳位的同步函數 Blynk.syncVirtual(V0) 向伺服器取得 V0 的值, 這會導致一個 V0 刷新動作, 使得 BLYNK_WRITE(V0) 被呼叫, 從而使 LED 以上次的設定閃爍. 以上測試 2 也同時回應了網友關於程式重新起始時, 滑桿之值不是停留在上一次設定值的問題.